[X4U] No PowerPC Apps Will Run Under Lion!

[Michael Burton]

On Feb 28, 2011, at 8:12 AM, Simon Forster wrote:

> On 28 Feb 2011, at 07:40, Randy B. Singer wrote:
> 
>> You can easily tell if your applications are PowerPC applications by highlighting their icons in the Finder, and choosing File —> Get Info.
>> 
>> In the resulting Get Info window, under General, if your application is a PowerPC application in will say so under Kind.
>> 
>> You can check several applications at the same time by holding down the shift key and clicking on all of the applications that you want to check to select all of them, and then choosing Get Info.
> 
> Alternatively, fire up activity monitor (Applications -> Utilities -> Activity Monitor), go to "View" menu -> "Columns". Make sure "Kind" is ticked. Spot the Power PC applications that you've got running.


Here's a quick-n-dirty Applescript to find PowerPC-only applications.

It takes a while for the Finder to return the list of application files (about 3 minutes on my system) -- that's why the long timeout on the Finder request. Also, note that this script checks only the Applications folder at the root of the startup disk. If you have applications elsewhere, you may want to modify the script.

This creates a text file listing PPC-only applications and the folders containing them. The file name is separated from the folder by a TAB character, so it should be simple to import the results into a database or spreadsheet. In a word processor, you may want to adjust tab settings to better separate the file names from the folders.

You may have PPC code in drivers, etc., that aren't standard Mac applications. At this point, I don't have a quick and reliable method for identifying those items.

Nevertheless, I hope this can be helpful.

----------

with timeout of 3600 seconds
	tell application "Finder"
		set all_apps to every application file of the entire contents of folder "Applications" of startup disk
	end tell
end timeout

set ppc_count to 0
set ppc_apps to "PowerPC Application" & tab & "Folder" & return & return
repeat with this_app in all_apps
	if kind of this_app contains "PowerPC" then
		set ppc_count to ppc_count + 1
		set ppc_apps to (ppc_apps & name of this_app & tab & (the container of this_app) as text) & return
	end if
end repeat

if ppc_count is 0 then
	display dialog "No PowerPC applications were found." buttons {"OK"} default button "OK"
else
	set report_file to choose file name default name "PPC Applications.txt"
	try
		set report_ref to open for access report_file with write permission
		write ppc_apps to report_ref
		close access report_file
	on error errMsg number errNum
		display alert "Error:" message errMsg & return & "Error number: " & errNum & "."
	end try
end if

----------

-- 
Michael Burton     michaelburton at brainrow.com     (614) 263-7948
Home Page (rarely updated) : http://pathetic.brainrow.com/
Blog (occasionally updated): http://brainrow.com/